blob: 771a67f642a17c49c3e010c4f7ffc810bca72daf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: Frederic Bezies <fredbezies at gmail dot com>
# Contributor: Michael Straube <michael.straubej@gmail.com>
# Contributor: pj1031999 <pj1031999@gmail.com>
# Contributor: Michal Docekal <docekal@gmail.com>
# Contributor: Laurie Clark-Michalek <bluepeppers (at) archlinux (dot) us>
pkgname=blockattack
pkgver=2.10.0
pkgrel=1
pkgdesc="Open source Tetris Attack clone"
arch=('i686' 'x86_64')
url="https://blockattack.net"
license=('GPL')
depends=('gcc-libs' 'glibc' 'boost-libs' 'sdl2' 'sdl2_mixer' 'sdl2_image' 'sdl2_ttf' 'physfs' 'hicolor-icon-theme')
makedepends=('cmake' 'boost' 'zip')
source=("$pkgname-$pkgver.tar.gz::https://github.com/blockattack/blockattack-game/archive/v$pkgver.tar.gz")
sha256sums=('6d9b4e0d58a733184d0bfac96869aea3ee5cc09185b15afe8e8d1510a61cc34b')
prepare() {
cd $pkgname-game-$pkgver
./packdata.sh
mkdir -p ../build
}
build() {
cd build
cmake ../$pkgname-game-$pkgver \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_POLICY_VERSION_MINIMUM=3.5
make
}
package() {
cd build
make DESTDIR="$pkgdir" install
}
|