blob: b2feea6b4af9bfc8ca0b1a07e9f5894b7be43f15 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: txtsd <aur.archlinux@ihavea.quest>
# Contributor: mrAppleXZ <mr.applexz@gmail.com>
pkgname=blockbench
_pkgname=Blockbench
pkgver=4.8.1
pkgrel=1
pkgdesc="A low-poly 3D model editor"
arch=('x86_64')
url="https://blockbench.net/"
license=('GPL3')
provides=(blockbench)
conflicts=(blockbench)
_pkgname=blockbench
_electron=electron
_electronDist=/usr/lib/${_electron}
_electronVersion=$(cat ${_electronDist}/version)
_electronVersionMajor=${_electronVersion%%.*}
depends=("${_electron}" 'giblib')
makedepends=(git npm)
source=("${_pkgname}::git+https://github.com/JannisX11/blockbench.git#tag=v${pkgver}"
"${_pkgname}.desktop")
sha256sums=('SKIP'
'74731a9f68dbef112c93dafee1a1a8665b9de0816f94643169419ad838dbf66c')
prepare() {
cd "${srcdir}/${_pkgname}"
npm install
}
build() {
cd "${srcdir}/${_pkgname}"
npm run dist -- --linux --x64 --dir -c.electronDist=${_electronDist} -c.electronVersion=${_electronVersion}
}
package() {
install -d "${pkgdir}/usr/"{bin,share/{pixmaps,applications}}
install -d "${pkgdir}/${_electronDist}${_electronVersionMajor}/resources"
echo -e "#!/bin/bash\nexec ${_electron} ${_electronDist}${_electronVersionMajor}/resources/${_pkgname}.asar \"\$@\"" > "${pkgdir}/usr/bin/${_pkgname}"
chmod 755 "${pkgdir}/usr/bin/${_pkgname}"
install "${srcdir}/${_pkgname}/icon.png" "${pkgdir}/usr/share/pixmaps/${_pkgname}.png"
install "${srcdir}/${_pkgname}.desktop" "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
install "${srcdir}/${_pkgname}/dist/linux-unpacked/resources/app.asar" "${pkgdir}${_electronDist}${_electronVersionMajor}/resources/${_pkgname}.asar"
cp -r "${srcdir}/${_pkgname}/dist/linux-unpacked/resources/app.asar.unpacked" "${pkgdir}${_electronDist}${_electronVersionMajor}/resources/${_pkgname}.asar.unpacked"
}
|