blob: e27431898267dee7fcfa0a6c54994dbf2d295391 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: Christian Schendel <doppelhelix@gmail.com>
pkgname=bluejay-git
pkgver=1.0.3.r5.g4d6d4e6
pkgrel=2
pkgdesc="Bluetooth manager written in Qt"
arch=(x86_64)
url="https://github.com/EbonJaeger/bluejay"
license=(
'CC0-1.0 AND CC-BY-SA-4.0 AND MPL-2.0'
)
depends=(
bluez-qt
glibc
hicolor-icon-theme
kcolorscheme
kcoreaddons
kdbusaddons
ki18n
kirigami
kirigami-addons
libstdc++
qqc2-desktop-style
qt6-base
qt6-tools
qt6-declarative
)
makedepends=(
appstream
extra-cmake-modules
git
ninja
vulkan-headers
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("${pkgname%-git}::git+$url.git")
b2sums=('SKIP')
pkgver() {
cd "${pkgname%-git}"
git describe --long --tags | sed -E 's/^v//;s/([^-]*-g)/r\1/;s/-/./g'
}
build() {
local cmake_options=(
-S "${pkgname%-git}"
-B build
-D CMAKE_BUILD_TYPE=None
-D CMAKE_INSTALL_PREFIX=/usr
-G Ninja
-W no-dev
)
cmake "${cmake_options[@]}"
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
install -Dm0644 -t "$pkgdir/usr/share/doc/${pkgname%-git}" \
"$srcdir/${pkgname%-git}/README.md"
}
# vim: set ft=sh ts=4 sw=4 et:
|