summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: b8e0137166eb1c5ea07b562a681dd707b8366520 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
# Maintainer: Silvio Fricke <silvio.fricke@gmail.com>
# Contributor: Martin Wimpress <code@flexion.org>

_pkgname=blueman
pkgname=${_pkgname}-git
pkgver=2.2.1.r40.g361046f1
pkgrel=1
pkgdesc="A GTK+ Bluetooth Manager (BlueZ 5) - git"
arch=('i686' 'x86_64')
license=('GPL')
url="https://github.com/blueman-project/blueman"
depends=('bluez' 'dbus-glib' 'gtk3' 'notification-daemon' 'libnotify'
         'polkit' 'python-cairo' 'python-dbus' 'python-gobject'
         'python-pybluez' 'startup-notification')
optdepends=('dnsmasq: DHCP server for Network Access Point'
            'pulseaudio: for some audio support')
makedepends=('cython' 'git' 'intltool' 'libtool')
conflicts=('blueman' 'blueman-bzr')
provides=('blueman')
source=("${pkgname}"::"git+https://github.com/blueman-project/${_pkgname}.git#branch=main")
sha1sums=('SKIP')
install=${pkgname}.install

pkgver() {
  cd "${srcdir}/${pkgname}"
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
    cd "${srcdir}/${pkgname}"
    NOCONFIGURE=1 ./autogen.sh
}

build() {
    cd "${srcdir}/${pkgname}"
    ./configure \
        --prefix=/usr \
        --sysconfdir=/etc \
        --libexecdir=/usr/lib/${_pkgname} \
        --with-gtk=3.0 \
        --disable-hal \
        --disable-sendto \
        --disable-static
    make
}

package() {
    cd "${srcdir}/${pkgname}"
    make DESTDIR="${pkgdir}" install
    chmod 0750 "${pkgdir}"/usr/share/polkit-1/rules.d
}