PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# Maintainer: Martin Rys <https://rys.rs/contact> | Toss a coin on https://rys.rs/donate

pkgname=bookstack
_camelname=BookStack
pkgver=24.12.1
pkgrel=1
pkgdesc='A simple, self-hosted, easy-to-use platform for organising and storing information'
arch=('any')
url="https://github.com/BookStackApp/BookStack"
license=('MIT')
# https://www.bookstackapp.com/docs/admin/installation/
depends=(
	'php'
	'php-gd'
)
optdepends=(
	'php-apache: webserver and a PHP implementation'
	'php-fpm: fastCGI'
	'mariadb: database'
	'nginx: webserver'
)
makedepends=('composer')
source=(
	"${pkgname}-${pkgver}.tar.gz::https://github.com/BookStackApp/BookStack/archive/v${pkgver}.tar.gz"
	'bookstack.conf'
)
sha256sums=('94303fbe47e202225c22ec45d67617cf9de0a17a576f973426435cd73cc4e64d'
            '82152fc91366d1bd623c559c03240f070e08d45a084a4c6e2e211f671bee8c78')
options=('!strip')
backup=("etc/webapps/${pkgname}/config.env")

package() {
	cd "${srcdir}/${_camelname}-${pkgver}"
	COMPOSER_ALLOW_SUPERUSER=1 composer install --no-dev --ignore-platform-reqs --no-interaction

	install -d "${pkgdir}/usr/share/webapps/${pkgname}" "${pkgdir}/usr/share/licenses/${pkgname}" "${pkgdir}/etc/webapps/${pkgname}"
	cp -r * "${pkgdir}/usr/share/webapps/${pkgname}"
	install -D "${srcdir}/${_camelname}-${pkgver}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}"

	cp .env.example "${pkgdir}/etc/webapps/${pkgname}/config.env"

	ln -s "/etc/webapps/${pkgname}/config.env" "${pkgdir}/usr/share/webapps/${pkgname}/.env"
	rm -rf "${pkgdir}/usr/share/webapps/${pkgname}/bootstrap/cache"

	mkdir -p "${pkgdir}/var/cache/${pkgname}"
	ln -s "/var/cache/${pkgname}" "${pkgdir}/usr/share/webapps/${pkgname}/bootstrap/cache"

	mkdir -p "${pkgdir}/var/lib"
	mv "${pkgdir}/usr/share/webapps/${pkgname}/storage" "${pkgdir}/var/lib/${pkgname}"
	ln -s "/var/lib/${pkgname}" "${pkgdir}/usr/share/webapps/${pkgname}/storage"

	install -Dm644 "${srcdir}/bookstack.conf" "${pkgdir}/usr/lib/tmpfiles.d/bookstack.conf"
}