blob: 5bc555edbfede509938590bf060fed98b185cd89 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Christopher Arndt <aur -at- chrisarndt -dot- de>
_name="BOops"
_pkgname="${_name,,}.lv2"
_plugin_uri="https://www.jahnichen.de/plugins/lv2/${_name}"
pkgname="${_pkgname}-git"
pkgdesc="A glitch effect sequencer LV2 plugin (git version)"
pkgver=1.2.4.r0.gbdb4de4
pkgrel=1
arch=('x86_64')
url="https://github.com/sjaehn/${_name}"
license=('GPL3')
groups=('lv2-plugins' 'pro-audio')
depends=('cairo' 'gcc-libs' 'glibc' 'libsndfile' 'libx11')
makedepends=('git' 'lv2')
checkdepends=('lv2lint')
provides=("${_name,,}" "${_name,,}=${pkgver//.r*/}" "${_pkgname}" "${_pkgname}=${pkgver//.r*/}")
conflicts=("${_name,,}" "${_pkgname}")
source=("${_pkgname}::git+https://github.com/sjaehn/${_name}")
md5sums=('SKIP')
pkgver() {
cd "${srcdir}/$_pkgname"
( set -o pipefail
git describe --long --tags 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
build() {
cd "${srcdir}/$_pkgname"
make
}
check() {
cd "${srcdir}/${_pkgname}"
lv2lint -Mpack -I "${_name}.lv2/" "${_plugin_uri}"
}
package() {
cd "$_pkgname"
make PREFIX="/usr" DESTDIR="$pkgdir/" install
install -vDm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
# Remove misplaced license file
find "${pkgdir}/usr/lib/lv2/${_name}.lv2" -type f -iname "*LICENSE*" -delete
}
|