blob: 0621ecb2b7700ef1d66adcc24a968fde1a98f9bd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Maintainer: Jannick Hemelhof <mister {dot} jannick {at} gmail {dot} com>
# Contributor: Nicola Squartini <tensor5 {at} gmail {dot} com>
# Contributor: NicoHood <aur {at} nicohood {dot} de>
# Contributor: Dick Choi <fluke8259 {at} gmail {dot} com>
# Contributor: Romain Bazile <gromain {dot} baz {at} gmail {dot} com>
pkgname=boostnote
_pkgname=Boostnote
pkgver=0.8.11
_pkgver=v.0.8.11
pkgrel=3
pkgdesc="Open source note-taking app for programmers"
arch=('any')
url="https://boostnote.io/"
license=('GPL3')
depends=('electron' 'nodejs')
makedepends=('npm' 'grunt-cli' 'git')
source=(
"${pkgname}-${pkgver}.tar.gz::https://github.com/BoostIO/"${_pkgname}"/archive/"${_pkgver}".tar.gz"
"${pkgname}.js"
"${pkgname}.desktop"
"warning-fix.patch"
"no-analytics.patch"
)
sha512sums=(
'bf3c640ced78c141299010012d75c2d391013446ec9f73ca5d7045112cad877a13094e9b6639b049f9e9d410652e46226717de363e0f74d880dd0549c1878fc7'
'f0abbdcca34d7f74d3dc66ffc2d0995416e7708c715d55fa58c4c2abc31d191ea42f3434e3105292b4817f83ac0ca89f456f5f93007ae80ab2426c8941f615f9'
'18bcda13580da8ceeaa86793a77ec00a053b8fd51451dad7e2b1a19553fe1a467ac647b44b789212e783f3f6a80968cc9404e884ef7ff6b1f6588473b3229d40'
'64fb4c4823744322b5777736fc1792fb377e433608b5456cb0e0b7053507d104a1bbe3fdc6fe193b41dfddadc1943e8220a27e26ec6d4166704f3e61e2572437'
'03588f657122a34874f2ededc4329df6b349f4c7a99015aa622b84aa7093cc611b975219eed773f7f8251db556dbb94f102e24dacdfb4a4e618ea2b6e4f25ef6'
)
prepare() {
cd "${_pkgname}-${_pkgver}"
patch -Np1 -i "${srcdir}/warning-fix.patch"
patch -Np1 -i "${srcdir}/no-analytics.patch"
}
build() {
cd "${_pkgname}-${_pkgver}"
npm install --no-optional
grunt compile
rm -r node_modules/
npm install --production --no-optional
}
package() {
cd "${_pkgname}-${_pkgver}"
appdir="/usr/lib/${pkgname}"
install -dm755 "${pkgdir}""${appdir}"
cp -a * "${pkgdir}""${appdir}"
install -Dm755 "${srcdir}/${pkgname}.js" "$pkgdir/usr/bin/${pkgname}"
install -Dm644 resources/app.png "$pkgdir/usr/share/pixmaps/${pkgname}.png"
install -Dm644 "${srcdir}/${pkgname}.desktop" "$pkgdir/usr/share/applications/${pkgname}.desktop"
# Remove stuff we do not need
find "${pkgdir}"/usr/lib/"${pkgname}"/node_modules \
-name "*.a" -exec rm '{}' \; \
-or -name "*.bat" -exec rm '{}' \; \
-or -name "*.node" -exec chmod a-x '{}' \; \
-or -name "benchmark" -prune -exec rm -r '{}' \; \
-or -name "doc" -prune -exec rm -r '{}' \; \
-or -name "html" -prune -exec rm -r '{}' \; \
-or -name "man" -prune -exec rm -r '{}' \; \
-or -path "*/less/gradle" -prune -exec rm -r '{}' \; \
-or -path "*/task-lists/src" -prune -exec rm -r '{}' \;
}
|