PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Maintainer: parov0z <andrey.android7890@gmail.com>

pkgname=bootsplash-manager-git
_pkgname=${pkgname//-git}
pkgver=1.10.r0.g74dc223
pkgrel=1
pkgdesc="Simple bootsplash manager"
url="https://github.com/parov0z/bootsplash-manager"
arch=(x86_64)
license=(GPL3)
depends=('qt5-base'
         'bootsplash-systemd'
         'kauth'
         'pamac'
         'sdl2')
conflicts=('bootsplash-manager-bin')

source=("git+https://github.com/parov0z/bootsplash-manager.git")
md5sums=('SKIP')

pkgver() {
     cd "$_pkgname"
     git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
     cd "${srcdir}"
     export CFLAGS+=" ${CPPFLAGS}"
     export CXXFLAGS+=" ${CPPFLAGS}"
     cmake -B build -S "${_pkgname}" \
           -DCMAKE_BUILD_TYPE='None' \
           -DCMAKE_INSTALL_PREFIX='/usr' \
           -Wno-dev
     make -C build
}

package() {    
     make DESTDIR="${pkgdir}" PREFIX="/usr" -C build install
}