blob: 5e81d7e8013decddd3a95337d88a854ea8876545 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Marco Huenseler <marco@wuthoehle.de>
pkgname=bootupd-git
_pkgname=bootupd
pkgver=0.2.34.r13.ge2c0dc9
pkgrel=1
pkgdesc="Bootloader updater"
arch=('x86_64' 'i686' 'armv6h' 'armv7h')
url="https://github.com/coreos/bootupd"
license=('Apache-2.0')
depends=(gcc-libs
glibc
grub
efibootmgr)
makedepends=(cargo
git)
provides=("bootupd=$pkgver")
conflicts=('bootupd')
source=("git+$url.git"
"0001-Modify-grub-paths-to-match-Arch-Linux.patch")
sha256sums=('SKIP'
'331cee421eab47415f9e4f0101ada3b0154db8ab42d2b2a4b4b7218ffb2ff3ca')
prepare() {
cd "$_pkgname"
patch -Np1 -i "${srcdir}/0001-Modify-grub-paths-to-match-Arch-Linux.patch"
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
pkgver() {
cd "$_pkgname"
git describe --long --tags --abbrev=7 --match="v*" HEAD |
sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$_pkgname"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
make
}
check() {
cd "$_pkgname"
RUST_BACKTRACE=1 cargo test
}
package() {
cd "$_pkgname"
make DESTDIR="$pkgdir" install
make DESTDIR="$pkgdir" install-grub-static
make DESTDIR="$pkgdir" install-systemd-unit
}
|