blob: 2534189b22554a45c04fae60b3f43f40d2b04699 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Lauri Niskanen <ape@ape3000.com>
# Contributor: Lukas Fleischer <lfleischer@archlinux.org>
# Contributor: Vlad M. <vlad@archlinux.net>
pkgname=borg-git
_pkgname=borg
pkgver=1.0.0.r27.gf0cb637
pkgrel=1
pkgdesc="Deduplicating backup program with compression and authenticated encryption"
url="https://borgbackup.github.io/"
license=('BSD')
arch=('i686' 'x86_64')
depends=('acl'
'lz4'
'openssl'
'python-msgpack'
'python-setuptools'
'xz')
optdepends=('openssh: repositories on remote hosts'
'python-llfuse: mounting backups as a FUSE filesystem')
makedepends=('cython'
'git'
'python-sphinx')
provides=('borg' 'borgbackup-git')
conflicts=('borg' 'borgbackup-git')
source=("${_pkgname}::git+https://github.com/borgbackup/${_pkgname}.git")
sha256sums=('SKIP')
pkgver() {
cd "${srcdir}/${_pkgname}"
git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "${srcdir}/${_pkgname}"
python setup.py build
cd docs
make man
}
package() {
cd "${srcdir}/${_pkgname}"
install -Dm644 "docs/_build/man/borg.1" "$pkgdir/usr/share/man/man1/borg.1"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
python setup.py -q install --root="$pkgdir" --optimize=1
}
|