summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: c76c99397c91c4f36ccea18979670c9fb7c8c058 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=botan-git
pkgver=2.7.0.r3.gf639dae0a
pkgrel=1
pkgdesc="Cryptography library written in C++"
arch=('i686' 'x86_64')
url="https://botan.randombit.net/"
license=('BSD')
depends=('glibc' 'zlib')
makedepends=('git' 'python')
provides=('botan')
conflicts=('botan')
options=('staticlibs')
source=("git+https://github.com/randombit/botan.git")
sha256sums=('SKIP')


pkgver() {
  cd "botan"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "botan"

  ./configure.py \
    --prefix="/usr" \
    --with-zlib
  make
}

check() {
  cd "botan"

  ./botan-test
}

package() {
  cd "botan"

  make DESTDIR="$pkgdir" install
  install -Dm644 "license.txt" "$pkgdir/usr/share/licenses/botan/license.txt"
}