blob: de7d0743085dd53001a9a7560ed9acf0a78adaea (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=boxbuddy
_app_id=io.github.dvlv.boxbuddyrs
pkgver=2.1.4
pkgrel=1
pkgdesc="A Graphical Interface for Distrobox"
arch=('x86_64')
url="https://github.com/Dvlv/BoxBuddyRS"
license=('MIT')
depends=('distrobox' 'libadwaita')
makedepends=('cargo')
checkdepends=('appstream')
options=('!lto')
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/$pkgver.tar.gz")
sha256sums=('9f470e5b7a2d75311f0bea91467d94e4c14f4b10d79c4b85a417f63b0990a297')
prepare() {
cd "BoxBuddyRS-$pkgver"
export CARGO_HOME="$srcdir/cargo-home"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}
build() {
cd "BoxBuddyRS-$pkgver"
# CFLAGS+=" -ffat-lto-objects" ## gettext-sys crate fails
export CARGO_HOME="$srcdir/cargo-home"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release --all-features
}
check() {
cd "BoxBuddyRS-$pkgver"
appstreamcli validate --no-net "${_app_id}.metainfo.xml"
desktop-file-validate "${_app_id}.desktop"
}
package() {
cd "BoxBuddyRS-$pkgver"
install -Dm755 "target/release/$pkgname-rs" -t "$pkgdir/usr/bin/"
install -Dm644 "${_app_id}.desktop" -t "$pkgdir/usr/share/applications/"
install -Dm644 "${_app_id}.gschema.xml" -t "$pkgdir/usr/share/glib-2.0/schemas/"
install -Dm644 "${_app_id}.metainfo.xml" -t "$pkgdir/usr/share/metainfo/"
install -Dm644 "icons/${_app_id}.svg" -t \
"$pkgdir/usr/share/icons/hicolor/scalable/apps/"
for lang in de_DE es it_IT pt_BR ru_RU uk_UA; do
install -Dm644 "po/${lang}/LC_MESSAGES/${pkgname}rs.mo" -t \
"$pkgdir/usr/share/locale/${lang}/LC_MESSAGES/"
done
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}
|