blob: eaa1ec5d4232c45dad0315e07c6fc5b882eb4dd6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Contributor: Greg White <gwhite@kupulau.com>
# Maintainer: Greg White <gwhite@kupulau.com>
pkgname=brave-dev-bin
pkgver=1.61.87
pkgrel=2
pkgdesc='Web browser that blocks ads and trackers by default (dev binary release).'
arch=(x86_64 aarch64)
url='https://brave.com/download-dev'
license=('MPL2')
depends=('gtk3' 'nss' 'alsa-lib' 'libxss' 'ttf-font')
optdepends=('cups: Printer support'
'mesa: Hardware accelerated rendering'
'libglvnd: Support multiple different OpenGL drivers at any given time'
'libgnome-keyring: gnome keyring support')
provides=("${pkgname}" 'brave-dev-browser')
conflicts=()
source=("MPL2::https://raw.githubusercontent.com/brave/browser-laptop/master/LICENSE.txt"
"$pkgname.sh")
options=(!strip)
source_x86_64=("https://github.com/brave/brave-browser/releases/download/v${pkgver}/brave-browser-dev_${pkgver}_amd64.deb")
source_aarch64=("https://github.com/brave/brave-browser/releases/download/v${pkgver}/brave-browser-dev_${pkgver}_arm64.deb")
sha512sums=('b8823586fead21247c8208bd842fb5cd32d4cb3ca2a02339ce2baf2c9cb938dfcb8eb7b24c95225ae625cd0ee59fbbd8293393f3ed1a4b45d13ba3f9f62a791f'
'd7d0cb581bd91227bff47a6b072a4c3da7d232383d6d207560c41bd5bb46eba7d1506dbf2a1da064ddda0194dfa35baec304db9f3fe81790734887d983c2e080')
sha512sums_x86_64=('8f89fb675e37c228b7e6ca7ddff1df8b6ee920e24590b4d849b1207fd83b31da0772e60cbc2d86f2ef1b29adff0ab166590258ddf122668908715cafcc5fe355')
sha512sums_aarch64=('351cf68988a229b9eacd0886337130bd7627385d4d1734f10b64002d3b8e76e84bcad6e2d73b9df7de9af3908c60e9cbfa152a2e0576ada9e5231b1ddbdbe18a')
prepare() {
mkdir -p brave
tar xf data.tar.xz -C brave
# Delete unneeded cron job
rm -rf brave/opt/brave.com/brave-dev/cron
# Use our script to launch (allows overriding flags, sets up data dir)
sed -i "s/\/usr\/bin\/brave-browser-dev/\/usr\/bin\/brave-dev/g" brave/usr/share/applications/brave-browser-dev.desktop
}
package() {
cp -a --reflink=auto brave/opt "$pkgdir/opt"
cp -a --reflink=auto brave/usr "$pkgdir/usr"
install -Dm0755 "$pkgname.sh" "$pkgdir/usr/bin/brave-dev"
install -Dm0644 "brave/opt/brave.com/brave-dev/product_logo_128_dev.png" "$pkgdir/usr/share/pixmaps/brave-browser-dev.png"
install -Dm0664 -t "$pkgdir/usr/share/licenses/$pkgname" "brave/opt/brave.com/brave-dev/LICENSE"
# allow firejail users to get the suid sandbox working
chmod 4755 "$pkgdir/opt/brave.com/brave-dev/chrome-sandbox"
}
|