blob: 3d2b8fcf5ebb9143800d2a8aa0755b724e9a03fd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Contributor: Greg White <gwhite@kupulau.com>
# Maintainer: Greg White <gwhite@kupulau.com>
pkgname=brave-nightly-bin
pkgver=1.54.6
pkgrel=1
pkgdesc='Web browser that blocks ads and trackers by default (nightly binary release).'
arch=(x86_64 aarch64)
url='https://brave.com/download-nightly'
license=('MPL2')
depends=('gtk3' 'nss' 'alsa-lib' 'libxss' 'ttf-font')
optdepends=('cups: Printer support'
'pepper-flash: Adobe Flash support'
'mesa: Hardware accelerated rendering'
'libglvnd: Support multiple different OpenGL drivers at any given time'
'libgnome-keyring: gnome keyring support')
provides=("${pkgname}" 'brave-nightly-browser')
conflicts=()
source=("MPL2::https://raw.githubusercontent.com/brave/browser-laptop/master/LICENSE.txt"
"$pkgname.sh")
options=(!strip)
source_x86_64=("https://github.com/brave/brave-browser/releases/download/v${pkgver}/brave-browser-nightly_${pkgver}_amd64.deb")
source_aarch64=("https://github.com/brave/brave-browser/releases/download/v${pkgver}/brave-browser-nightly_${pkgver}_arm64.deb")
sha512sums=('b8823586fead21247c8208bd842fb5cd32d4cb3ca2a02339ce2baf2c9cb938dfcb8eb7b24c95225ae625cd0ee59fbbd8293393f3ed1a4b45d13ba3f9f62a791f'
'191500db5dd9692d362745e0055f9ac570c7ca2043edcf3e2eb9dcf8039615022f3459c909ed29d89410886481723d2d439086f1938249674ea32654819190c4')
sha512sums_x86_64=('95980d247a65ec22c8bf26fcc577d19e0542c5906ed7d6cc124b7aab279abb0237d6ee9c4b73474c0c92d595f69e49f9156d6dcde57c1bb42442596400f56e44')
sha512sums_aarch64=('4dff8be4f0cfacffe5ea9c56ba2621e45123c36e5f63e9b361c6ae324b13f6deafa0ee9ed99890ebfe98fce66e539042583d44ead9fd35011aed01680eb74cb3')
prepare() {
mkdir -p brave
tar xf data.tar.xz -C brave
# Delete unneeded cron job
rm -rf brave/opt/brave.com/brave-nightly/cron
# Use our script to launch (allows overriding flags, sets up data dir)
sed -i "s/\/usr\/bin\/brave-browser-nightly/\/usr\/bin\/brave-nightly/g" brave/usr/share/applications/brave-browser-nightly.desktop
}
package() {
cp -a --reflink=auto brave/opt "$pkgdir/opt"
cp -a --reflink=auto brave/usr "$pkgdir/usr"
install -Dm0755 "$pkgname.sh" "$pkgdir/usr/bin/brave-nightly"
install -Dm0644 "brave/opt/brave.com/brave-nightly/product_logo_128_nightly.png" "$pkgdir/usr/share/pixmaps/brave-browser-nightly.png"
install -Dm0664 -t "$pkgdir/usr/share/licenses/$pkgname" "brave/opt/brave.com/brave-nightly/LICENSE"
# allow firejail users to get the suid sandbox working
chmod 4755 "$pkgdir/opt/brave.com/brave-nightly/chrome-sandbox"
}
|