summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: f292d5ab14a13918495268d8e5f1b10a20ff5460 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
# Maintainer: Frederic Bezies <fredbezies at gmail dot com>
# Based on work made by Dustin Falgout <dustin@antergos.com>

pkgname=brisk-menu-git
_gitname=brisk
pkgver=v0.5.0.r30.gc274131
pkgrel=2
pkgdesc='Modern, efficient menu for the MATE Desktop Environment - git version'
arch=('i686' 'x86_64')
url='https://github.com/getsolus/brisk-menu'
license=('GPL2')
groups=('mate')
depends=('mate-panel' 'libnotify')
makedepends=('gnome-common' 'gettext' 'itstool' 'vala>=0.36' 'meson' 'ninja')
optdepends=('mozo: for menu edition'
		'menulibre: for menu edition') 
options=('!libtool' '!emptydirs')
provides=('brisk-menu')
conflicts=('brisk-menu')
source=(git+https://github.com/getsolus/brisk-menu.git
        mate-122.patch
        fix-launch.patch)
sha1sums=('SKIP'
          '64641c7c67e357220cab52e48a7518e1d99a04b1'
          '57a888511a70142ee4c1b192cc50ee12661e84d7')

pkgver() {
    cd "$srcdir/brisk-menu"
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}


prepare() {
    cd "$srcdir/brisk-menu"
    # This patch fixes building with mate 1.22.x
    patch -Np1 -i "${srcdir}/mate-122.patch"
    # This fixes starting with mate 1.22.x but removes categories icon for now
    patch -Np1 -i "${srcdir}/fix-launch.patch"
}

build() {
    cd "$srcdir/brisk-menu"
    meson --buildtype plain build --prefix=/usr
    ninja -C build -j$(($(getconf _NPROCESSORS_ONLN)+1))
}


package() {
    cd "$srcdir/brisk-menu"
    DESTDIR="$pkgdir" ninja -C build install
}