blob: 9fd4948cc07ddbdc7f48116fd6122cb5a2383654 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Pierce Thompson <insprill@gmail.com>
pkgname=bs-manager-git
pkgver=v1.4.0.r43.g7ff0fe5
pkgrel=4
pkgdesc="An all-in-one tool for managing Beat Saber versions, maps, mods, and more"
arch=("x86_64")
url="https://github.com/Zagrios/bs-manager"
license=('GPL')
depends=('libvips' 'dotnet-runtime-6.0' 'dotnet-runtime-3.1' 'libicu50' 'screen')
makedepends=('git' 'nvm' 'npm')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=(
'git+https://github.com/Zagrios/bs-manager.git'
"${pkgname%-git}.desktop"
)
sha256sums=(
'SKIP'
'bf6dfa24f649ad4f2f1d0b6326f2ee020bf820fdb69ba7269225df61c4eeb2f4'
)
pkgver() {
cd "${pkgname%-git}"
git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${pkgname%-git}"
command -v nvm >/dev/null && nvm deactivate && nvm unload
export NVM_DIR="${srcdir}/.nvm"
source /usr/share/nvm/init-nvm.sh || [[ $? != 1 ]]
nvm install 20
nvm use 20
}
build() {
cd "${pkgname%-git}"
npm install
npm run package
}
package() {
cd "${pkgname%-git}"
local build_dir="release/build/linux-unpacked"
local license_dir="$pkgdir/usr/share/licenses/${pkgname%-git}"
install -d "$pkgdir/opt/${pkgname%-git}"
cp -r "$build_dir/". "$pkgdir/opt/${pkgname%-git}/"
install -Dm644 "$srcdir/bs-manager.desktop" "$pkgdir/usr/share/applications/${pkgname%-git}.desktop"
install -Dm644 "resources/readme/SVG/icon.svg" "$pkgdir/usr/share/pixmaps/${pkgname%-git}.svg"
install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/${pkgname%-git}"
install -Dm644 "README.md" -t "$pkgdir/usr/share/doc/${pkgname%-git}"
}
|