blob: a773d4fa03a523825bcf850492decb207f6bc925 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Vekhir <vekhir AT yahoo DOT com>
# Contributor: Jiuyang Liu <liujiuyang1994@gmail.com>
# Contributor: Paulo Matias <matias@ufscar.br>
pkgname=bsc
pkgver=2026.07
pkgrel=1
pkgdesc='Bluespec Compiler (BSC)'
arch=('x86_64')
url='https://github.com/B-Lang-org/bsc'
license=('BSD-3-Clause')
depends=('haskell-old-time' 'haskell-syb' 'haskell-regex-compat' 'haskell-split'
'haskell-strict-concurrency')
makedepends=('git' 'gperf' 'ghc' 'tcl' 'texlive-latexextra' 'texlive-fontsextra')
checkdepends=('dejagnu' 'iverilog' 'pkg-config' 'systemc' 'tcsh' 'time')
optdepends=('tcl: bluesim and bluetcl')
source=("git+https://github.com/b-lang-org/bsc.git#tag=$pkgver"
"git+https://github.com/SRI-CSL/yices2.git#commit=f705557b7d33d866eb1b47b5471f97189eb31cc4")
sha256sums=('5dc7794ef10d5f0ecb42f3029f0e32e47d88b7ca770919ad645c99a654174c08'
'7b2e722085456721b8127606a9b209aa6c4ad6b67bd0558cd09cfeda12281971')
_prefix="/opt/bsc"
prepare() {
cd "$srcdir/bsc"
git submodule init
git config submodule.externals/vendor/yices/v2.6/yices2.url "$srcdir/yices2"
git submodule update
}
build(){
# prevent static lib mangling with LTO (pacman#150, bsc#704)
CXXFLAGS+=" -ffat-lto-objects"
cd "$srcdir/bsc"
make GHC="ghc -dynamic" GHCJOBS=4 GHCRTSFLAGS='+RTS -A128m -RTS' install-src
make install-doc
}
check() {
cd "$srcdir/bsc"
# Currently failing due to https://github.com/B-Lang-org/bsc/issues/949
# Requires https://gitlab.archlinux.org/archlinux/packaging/packages/systemc/-/merge_requests/1
make check-suite-parallel || echo "Tests failed"
}
package() {
cd "$srcdir/bsc"
install -d "${pkgdir}${_prefix}"
cp -dr --preserve=mode,timestamp ./inst/* "${pkgdir}${_prefix}"
install -d "${pkgdir}/usr/bin"
local _prog
for _prog in bsc bluetcl; do
sed -i "s,^BINDIR=.*$,BINDIR=${_prefix}/bin," "${pkgdir}${_prefix}/bin/${_prog}"
ln -s "${_prefix}/bin/${_prog}" "${pkgdir}/usr/bin"
done
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -d "${pkgdir}/usr/share/vim/vimfiles"
cp -dr --preserve=mode,timestamp ./util/vim/{ftdetect,indent,syntax} "${pkgdir}/usr/share/vim/vimfiles"
}
|