PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer: Ayush Agarwal <ayushnix at fastmail dot com>
# Contributor: Ben Oliver <ben at bfoliver dot com>
# Contributor: Andy Weidenbaum <archbaum at gmail dot com>
# Contributor: John Jenkins <twodopeshaggy at gmail dot com>
# Contributor: Julian Paul Dasmarinas <julian.dasma at gmail dot com>

pkgname=buku
pkgver=4.8
pkgrel=1
pkgdesc="Bookmark manager like a text-based mini-web"
arch=('any')
url="https://github.com/jarun/buku"
license=('GPL')
depends=('ca-certificates'
  'python-beautifulsoup4'
  'python-cryptography'
  'python-html5lib'
  'python-urllib3')
makedepends=('python-setuptools')
optdepends=('wl-clipboard: to copy text in wayland'
  'wl-clipboard-rs: to copy text in wayland'
  'xsel: to copy text in xorg'
  'xclip: to copy text in xorg')
conflicts=('buku-git')
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('a0b94210e80e9f9f359e5308323837d41781cf8dba497341099d5c59e27fa52c')

package() {
  cd "$pkgname-$pkgver" 2> /dev/null || {
    printf "%s\n" "unable to cd to $pkgname-$pkgver"
    exit 1
  }
  export PYTHONHASHSEED=0
  python setup.py install --root="$pkgdir" --prefix=/usr --optimize=1

  local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
  rm -f "$pkgdir"/usr/bin/bukuserver
  rm -rf "$pkgdir/$site_packages"/bukuserver
  gzip -f buku.1

  install -Dm644 auto-completion/fish/buku.fish "${pkgdir}/usr/share/fish/vendor_completions.d/buku.fish"
  install -Dm644 auto-completion/bash/buku-completion.bash "${pkgdir}/usr/share/bash-completion/completions/buku"
  install -Dm644 auto-completion/zsh/_buku "${pkgdir}/usr/share/zsh/site-functions/_buku"
  install -Dm644 buku.1.gz "${pkgdir}/usr/share/man/man1/buku.1.gz"
}