summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 0f81b73727fb58392a148b17db7c5838ad9d98d6 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
# Maintainer: Gordian Edenhofer <gordian.edenhofer@gmail.com>
# Contributor: Michael Witten <mfwitten>
# Contributor: Matthieu Rakotojaona <rakoo>

pkgname=bup-git
epoch=1
pkgver=0.32.r0.g3b052c63
pkgrel=1
pkgdesc='Efficient file backup system based on the git packfile format'
arch=('i686' 'x86_64')
url='https://bup.github.io/'
license=('GPL')
depends=('python-fuse' 'par2cmdline' 'python-pyxattr' 'acl' 'readline' 'attr' 'git')
optdepends=('python-tornado: launch a web server to examine backup sets'
	'readline: FTP access'
	'par2cmdline: error correction'
	'python-pytest-xdist: parallel tests')
makedepends=('pandoc')
checkdepends=('rsync' 'python-pytest')
provides=("bup=${pkgver}")
conflicts=("bup")
source=("${pkgname}"::"git+https://github.com/bup/bup.git")
sha512sums=('SKIP')

pkgver() {
	cd "${srcdir}/${pkgname}"
	( set -o pipefail
	git describe --long 2>/dev/null | sed 's/^slurm-//;s/\([^-]*-g\)/r\1/;s/-/./g' \
	|| printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
	)
}

prepare() {
	cd "${srcdir}/${pkgname}"

	# Configure the program to use python3 everywhere
	PYTHON=/usr/bin/python3 ./configure
}

build() {
	make -C "${srcdir}/${pkgname}"
}

check() {
	make -C "${srcdir}/${pkgname}" test
}

package() {
	make -C "${srcdir}/${pkgname}" DESTDIR="${pkgdir}" PREFIX="/usr" install
}