blob: 79940a29997cd5728cf50e797de64a7fe5e3ec69 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: George Rawlinson <george@rawlinson.net.nz>
pkgname=bupstash
pkgver=0.10.3
pkgrel=1
pkgdesc="A tool for encrypted backups"
arch=('x86_64')
url="https://github.com/andrewchambers/bupstash"
license=('MIT')
depends=('libsodium' 'gcc-libs')
makedepends=('rust' 'ruby-ronn-ng')
checkdepends=('bash-bats' 'python') # if you hate yourself, add procps-ng + bubblewrap
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('5968e063fd7c97bb85cdcdf6fa95146030f6149e6919722f26642187fa6fced52de68615e91a5202d2880357527c517f2711a5e04d00a1908b6081ccf886e47b')
b2sums=('071887a598f0767fdf6b0224800286d75be3ad48b5df57575138c4ff24f05bb68089f7e65c531892589c307c4cb612cc716f6769105793e20b0c92228f3da006')
prepare() {
cd "$pkgname-$pkgver"
# download dependencies
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}
build() {
cd "$pkgname-$pkgver"
cargo build --release --frozen --all-features
}
check() {
cd "$pkgname-$pkgver"
# run cargo tests
cargo test
# run cli tests
# ensure recently-built binary is first in $PATH
PATH="$(pwd)/target/release:$PATH"
bats ./cli-tests
}
package() {
cd "$pkgname-$pkgver"
# binary
install -vDm755 -t "$pkgdir/usr/bin" "target/release/$pkgname"
# license
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
# documentation
install -vd "$pkgdir/usr/share/doc/$pkgname"
cp -vr doc/* "$pkgdir/usr/share/doc/$pkgname"
rm -vrf "$pkgdir/usr/share/doc/$pkgname/man"
# man pages
OLDIFS="$IFS"
IFS="."
cd doc/man
for filename in *; do
read -ra PART <<< "$filename"
title="${PART[0]}"
section="${PART[1]}"
# generate man directory if required
if [ ! -d "$pkgdir/usr/share/man/man${section}" ]; then
install -vd "$pkgdir/usr/share/man/man${section}"
fi
# generate man page
ronn --roff \
<"$filename" \
>"$pkgdir/usr/share/man/man${section}/${title}.${section}"
done
IFS="$OLDIFS"
unset OLDIFS
}
|