blob: 1a7adf6b42cf65cdb403bb2822a2da62ace112bc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# Maintainer: George Rawlinson <george@rawlinson.net.nz>
pkgname=bupstash
pkgver=0.11.0
pkgrel=1
pkgdesc="A tool for encrypted backups"
arch=('x86_64')
url="https://github.com/andrewchambers/bupstash"
license=('MIT')
depends=('libsodium' 'gcc-libs')
makedepends=('git' 'rust' 'ruby-ronn-ng')
checkdepends=('bash-bats' 'python') # if you hate yourself, add procps-ng + bubblewrap
options=('!lto')
_commit='534c10a86af420b9edf2835c5232b085c38b79fc'
source=("$pkgname::git+$url.git#commit=$_commit")
b2sums=('SKIP')
pkgver() {
cd "$pkgname"
git describe --tags | sed 's/^v//'
}
prepare() {
cd "$pkgname"
# download dependencies
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}
build() {
cd "$pkgname"
cargo build --release --frozen --all-features
}
check() {
cd "$pkgname"
# run cargo tests
cargo test
# run cli tests
# ensure recently-built binary is first in $PATH
PATH="$(pwd)/target/release:$PATH"
bats ./cli-tests
}
package() {
cd "$pkgname"
# binary
install -vDm755 -t "$pkgdir/usr/bin" "target/release/$pkgname"
# license
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
# documentation
install -vd "$pkgdir/usr/share/doc/$pkgname"
cp -vr doc/* "$pkgdir/usr/share/doc/$pkgname"
rm -vrf "$pkgdir/usr/share/doc/$pkgname/man"
# man pages
OLDIFS="$IFS"
IFS="."
cd doc/man
for filename in *; do
read -ra PART <<< "$filename"
title="${PART[0]}"
section="${PART[1]}"
# generate man directory if required
if [ ! -d "$pkgdir/usr/share/man/man${section}" ]; then
install -vd "$pkgdir/usr/share/man/man${section}"
fi
# generate man page
ronn --roff \
<"$filename" \
>"$pkgdir/usr/share/man/man${section}/${title}.${section}"
done
IFS="$OLDIFS"
unset OLDIFS
}
|