blob: 3833c7550f0861994f59745d45ca7433640cb542 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: linuxer <linuxer@artixlinux.org>
# Maintainer: Josef Miegl <josef@miegl.cz>
# Contributor: goll <adrian.goll+aur[at]gmail>
# Contributor: Kosava <kosava@gmail.com>
pkgname=butt
pkgver=0.1.30
pkgrel=1
pkgdesc="Easy to use, multi OS streaming tool"
arch=('i686' 'x86_64' 'aarch64' 'armv7h')
license=('GPL2')
url="http://butt.sourceforge.net/"
depends=('fltk' 'dbus' 'portaudio' 'libfdk-aac' 'libvorbis' 'libogg' 'lame' 'flac' 'opus' 'libsamplerate')
source=(${pkgname}-${pkgver}.tar.gz::"http://sourceforge.net/projects/${pkgname}/files/${pkgname}/${pkgname}-${pkgver}/${pkgname}-${pkgver}.tar.gz")
b2sums=('5bf0bf6ece4f9d271c376dad7aac653b6f0c67d6c5bb7ff8cdd55adb56bd9f20665822f625242ba79569784bbeaa9fa534d687be4cdc0ae55a47c77a49e50036')
build() {
cd "${pkgname}-${pkgver}"
./configure --prefix=/usr
make
}
package() {
cd "${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
# Desktop file
install -Dm644 "usr/share/applications/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
# Icons
for size in 16 22 24 32 48 64 96 128 256 512; do
format="${size}x${size}"
install -Dm644 "icons/icon_${format}.png" "${pkgdir}/usr/share/icons/hicolor/${format}/apps/${pkgname}.png"
done
install -Dm644 "icons/icon_scalable.svg" "${pkgdir}/usr/share/icons/hicolor/scalable/apps/${pkgname}.svg"
# Documentation
for doc in AUTHORS ChangeLog KNOWN_BUGS NEWS README THANKS; do
install -Dm644 "${doc}" "${pkgdir}/usr/share/doc/${pkgname}/${doc}"
done
# Pixmaps
for file in usr/share/pixmaps/"${pkgname}"*; do
filename=`basename "${file}"`
install -Dm644 "${file}" "${pkgdir}/usr/share/pixmaps/${filename}"
done
}
# vim:set ts=2 sw=2 et:
|