blob: 891a462f05cde22647db654040f6e462daea7870 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Maintainer: ugjka <esesmu@protonmail.com>
pkgname=calendar
pkgver=6.5_20190812
_pkgverbase=6.5
pkgrel=2
pkgdesc="Reminder utility (OpenBSD)"
url="http://www.openbsd.org/cgi-bin/cvsweb/src/usr.bin/calendar"
arch=('x86_64')
license=('BSD')
makedepends=("cvs" "openssh")
conflicts=("bsdmainutils")
source=("git+https://github.com/ugjka/calendar.latvia.git"
"http://ftp.debian.org/debian/pool/main/b/bsdmainutils/bsdmainutils_11.1.2.tar.gz"
"calendar-linux.patch"
"Makefile.linux"
"LICENSE")
sha256sums=('SKIP'
'101c0dede5f599921533da08a46b53a60936445e54aa5df1b31608f1407fee60'
'3dd187a4bcb49e5e1b10e70338e3bff800d0fc6822024daa73326bb6351a210f'
'e29cd94c128ecf76cb5224bd5dea4a2b199773f27226484b17804b83f6e8462a'
'95112fa05d9b7204808ede37b1c77469826c8c3875e4b1523307b5050d966564')
TAG="OPENBSD_${_pkgverbase/./_}"
pkgver(){
cd "${SRCDEST}"/${pkgname}-${_pkgverbase}
date=$(cvs -q log -l | awk '/date:/ { gsub("/",""); if ($2 > n) n = $2;} END { print n; }')
echo "${_pkgverbase}_${date}"
}
prepare() {
cd "${SRCDEST}"
CVS_RSH=ssh ; export CVS_RSH
cvs -d anoncvs@obsdacvs.cs.toronto.edu:/cvs co \
-d ${pkgname}-${_pkgverbase} -r ${TAG} src/usr.bin/${pkgname}
cp -a ${pkgname}-${_pkgverbase} "${srcdir}"
cd "${srcdir}"/${pkgname}-${_pkgverbase}
patch -p1 < ../calendar-linux.patch
sed -i 's|/usr/libexec/tradcpp|/usr/bin/cpp|' pathnames.h
cp ../Makefile.linux Makefile
# import latvian calendar from ugjka's repo
cp ../calendar.latvia/calendar.latvia calendars/
# import some calendars from debian
cp ../bsdmainutils/usr.bin/calendar/calendars/calendar.australia calendars/
cp ../bsdmainutils/usr.bin/calendar/calendars/calendar.freebsd calendars/
cp ../bsdmainutils/usr.bin/calendar/calendars/calendar.southafrica calendars/
cp ../bsdmainutils/usr.bin/calendar/calendars/calendar.lotr calendars/
cp ../bsdmainutils/usr.bin/calendar/calendars/calendar.dutch calendars/
cp ../bsdmainutils/debian/calendars/calendar.argentina calendars/
cp ../bsdmainutils/debian/calendars/calendar.belgium calendars/
cp ../bsdmainutils/debian/calendars/calendar.debian calendars/
cp ../bsdmainutils/debian/calendars/calendar.eu calendars/
cp ../bsdmainutils/debian/calendars/calendar.kazakhstan calendars/
cp ../bsdmainutils/debian/calendars/calendar.thai calendars/
cp ../bsdmainutils/debian/calendars/calendar.ubuntu calendars/
}
build() {
cd ${pkgname}-${_pkgverbase}
make
}
package() {
cd ${pkgname}-${_pkgverbase}
make DESTDIR="${pkgdir}" install
install -Dm644 ../LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}
|