PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Maintainer: A Frederick Christensen <aur@ivories.org>
# Contributor: Tobias Brox <t-arch@tobixen.no>
pkgname="calendar-cli-git"
_pkgname="calendar-cli"
pkgver=r286.2dd2577
pkgrel=2
pkgdesc="calendar-cli is a caldav client for calendar and task management"
url="https://github.com/tobixen/calendar-cli"
arch=('any')
license=('GPL')
provides=('calendar-cli')
conflicts=('calendar-cli')
depends=('python'
	 'python-caldav>=0.11.0'
	 'python-icalendar'
	 'python-pytz'
	 'python-vobject'
	 'python-tzlocal'
	 'python-six')
makedepends=('python-build'
	     'python-installer'
	     'python-pytest'
	     'python-setuptools'
	     'python-wheel')
source=("${pkgname}::git+https://github.com/tobixen/${_pkgname}")
sha256sums=('SKIP')

pkgver(){
  cd "${pkgname}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

build() {
  cd "${pkgname}"
  python -m build --wheel --no-isolation
}

check() {
  cd "${pkgname}"
  pytest
}

package() {
  cd "${pkgname}"
  python -m installer --destdir="$pkgdir" dist/*.whl
}