blob: e82690ebe0146746b70fbf276de20615d3ed3d86 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Paul Hentschel <aur at hpminc dot com>
pkgname=camotics-git
pkgver=r822.8d1c8fb
pkgrel=1
pkgdesc="3-axis NC machining simulation software"
arch=('x86_64')
url="http://camotics.org/"
license=('GPL2')
depends=(
'v8-3.14'
'qt5-websockets'
'cairo'
'desktop-file-utils'
)
makedepends=(
'git'
'scons'
'python2-six'
'qt5-tools'
'cbang-git'
)
provides=('camotics')
conflicts=('camotics')
source=(
"${pkgname%-*}::git+https://github.com/CauldronDevelopmentLLC/CAMotics.git"
)
sha256sums=('SKIP')
pkgver() {
cd "${pkgname%-*}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "${pkgname%-*}"
sed -i '24 i env.Append(LINKFLAGS = os.environ.get("LDFLAGS"))' SConstruct
}
build() {
cd "${pkgname%-*}"
CBANG_HOME=/opt/cbang scons
}
package() {
cd "${pkgname%-*}"
CBANG_HOME=/opt/cbang scons install install_prefix="$pkgdir/usr"
install -d "$pkgdir/usr/share/${pkgname%-*}"/tpl_lib
cp -a tpl_lib/ "$pkgdir/usr/share/${pkgname%-*}"
install -Dm644 -t "$pkgdir"/usr/share/applications CAMotics.desktop
install -Dm644 -t "$pkgdir"/usr/share/pixmaps images/camotics.png
install -Dm644 -t "$pkgdir/usr/share/doc/${pkgname%-*}" README.md CHANGELOG.md COPYING LICENSE
# install examples and machines
install -d "$pkgdir/usr/share/doc/${pkgname%-*}"/{examples,machines}
cp -a {examples/,machines/} "$pkgdir/usr/share/doc/${pkgname%-*}"
}
# vim:set ts=2 sw=2 et:
|