summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 9d9dd29ae713e55926aad0e1570db7bb00e82424 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
# Maintainer: Justin R. St-Amant <jstamant24 at gmail dot  com>
pkgname=camotics-git
pkgver=1.0.6.r127.g776b29b
pkgrel=2
pkgdesc="3-axis NC machining simulation software"
arch=('i686' 'x86_64')
url="http://camotics.org/"
license=('GPL2')
depends=('boost-libs'
         'bzip2'
         'cairo'
         'expat'
         'glu'
         'libffi'
         'libgl'
         'libmariadbclient'
         'openssl'
         'qt4'
         'sqlite'
         'v8'
         'zlib')
makedepends=('boost' 'scons')
provides=('camotics')
replaces=('openscam')
source=("$pkgname::git+https://github.com/CauldronDevelopmentLLC/CAMotics.git"
        "git+https://github.com/CauldronDevelopmentLLC/cbang.git"
        "camotics.desktop")
md5sums=('SKIP' 'SKIP' 'bca9df64570c6c6e6773e8428e27cfb8')

pkgver() {
  cd "$srcdir/$pkgname"
  git describe --long --tags | sed 's/^v//;s/-/.r/;s/-/./'
}

build() {
  cd "$srcdir/cbang"
  scons qt_version=4
  export CBANG_HOME=$PWD

  cd "$srcdir/$pkgname"
  scons qt_version=4
}

package() {
  cd "$srcdir"
  install -Dm644 "camotics.desktop" \
          "$pkgdir/usr/share/applications/camotics.desktop"
  cd "$srcdir/$pkgname"
  install -Dm644 "images/camotics.png" "$pkgdir/usr/share/pixmaps/camotics.png"
  scons install compiler=gnu install_prefix="$pkgdir/usr" qt_version=4
}