blob: e5e3e37a34a6e85099dccb0d9def3e08e737e9c2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=canu-git
pkgver=2.2.r89.g769108f4b
pkgrel=1
pkgdesc="A fork of the Celera Assembler designed for high-noise single-molecule sequencing"
arch=('i686' 'x86_64')
url="https://canu.readthedocs.io/"
license=('custom')
depends=('glibc' 'java-runtime' 'perl')
makedepends=('git')
optdepends=('gnuplot')
provides=("canu=$pkgver")
conflicts=('canu')
options=('staticlibs')
source=("git+https://github.com/marbl/canu.git")
sha256sums=('SKIP')
prepare() {
cd "canu"
git submodule update --init --recursive
}
pkgver() {
cd "canu"
_tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9\.]+$' | head -n1)
_rev=$(git rev-list --count $_tag..HEAD)
_hash=$(git rev-parse --short HEAD)
printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}
build() {
cd "canu"
make -C "src"
}
package() {
cd "canu"
install -Dm755 "build/bin"/* -t "$pkgdir/usr/bin"
install -Dm644 "build/lib/site_perl/canu"/*.pm -t "$pkgdir/usr/lib/site_perl/canu"
install -Dm644 "build/share/java/classes"/*.jar -t "$pkgdir/usr/share/java/classes"
install -Dm644 "build/lib"/*.a -t "$pkgdir/usr/lib"
install -Dm644 "README.licenses" -t "$pkgdir/usr/share/licenses/canu"
}
|