blob: 6b260bed58f9ba2a5ff5845d6661901d1b2fd9bf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
# Maintainer: Mario Finelli <mario at finel dot li>
pkgname=capistrano
pkgver=3.17.2
pkgrel=1
pkgdesc="A remote server automation and deployment tool written in Ruby"
arch=(any)
url=https://capistranorb.com
license=(MIT)
options=(!emptydirs)
depends=(ruby ruby-airbrussh ruby-i18n ruby-rake ruby-sshkit)
checkdepends=(ruby-mocha ruby-rspec)
makedepends=(ruby-rdoc rubygems)
source=(https://github.com/capistrano/capistrano/archive/v${pkgver}/$pkgname-$pkgver.tar.gz)
sha256sums=('cf555b47b5051bcaada6c710cd198bc53cf79db02d75901c0c495e6676eb8902')
prepare() {
cd $pkgname-$pkgver
sed -i 's|~>|>=|g' ${pkgname}.gemspec
sed -i 's|git ls-files -z|find -print0|' ${pkgname}.gemspec
sed -i '/cucumber/Id' Rakefile
# disable failed version-check test
sed -i '/prints the Capistrano version/,+4d' \
spec/lib/capistrano/doctor/gems_doctor_spec.rb
}
build() {
cd $pkgname-$pkgver
local _gemdir="$(gem env gemdir)"
gem build "${pkgname}.gemspec"
gem install \
--local \
--verbose \
--ignore-dependencies \
--no-user-install \
--install-dir "tmp_install/${_gemdir}" \
--bindir "tmp_install/usr/bin" \
"${pkgname}-${pkgver}.gem"
# remove unrepreducible files
rm --force --recursive --verbose \
"tmp_install/${_gemdir}/cache/" \
"tmp_install/${_gemdir}/gems/${pkgname}-${pkgver}/vendor/" \
"tmp_install/${_gemdir}/doc/${pkgname}-${pkgver}/ri/ext/"
find "tmp_install/${_gemdir}/gems/" \
-type f \
\( \
-iname "*.o" -o \
-iname "*.c" -o \
-iname "*.so" -o \
-iname "*.time" -o \
-iname "gem.build_complete" -o \
-iname "Makefile" \
\) \
-delete
find "tmp_install/${_gemdir}/extensions/" \
-type f \
\( \
-iname "mkmf.log" -o \
-iname "gem_make.out" \
\) \
-delete
}
check() {
cd $pkgname-$pkgver
local _gemdir="$(gem env gemdir)"
GEM_HOME="tmp_install/${_gemdir}" rake spec
}
package() {
cd $pkgname-$pkgver
cp --archive --verbose tmp_install/* "${pkgdir}"
install -v -Dm0644 LICENSE* "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -v -Dm0644 CHANGELOG.md -t "${pkgdir}/usr/share/doc/${pkgname}"
install -v -Dm0644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
}
# vim: set ts=2 sw=2 et:
|