blob: 0e9e12d3618abd726802c91f3f1c1b29f88777b8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: George Rawlinson <grawlinson@archlinux.org>
pkgname=cargo-make
pkgver=0.36.1
pkgrel=1
pkgdesc='Rust task runner and build tool'
arch=('x86_64')
url='https://github.com/sagiegurari/cargo-make'
license=('Apache')
depends=('gcc-libs' 'openssl')
makedepends=('git' 'rust')
options=('!lto')
_commit='2d6bb6be3de230fe3b09ca07bea87a50119a3432'
source=("$pkgname::git+$url.git#commit=$_commit")
b2sums=('SKIP')
pkgver() {
cd "$pkgname"
git describe --tags | sed 's/^v//'
}
prepare() {
cd "$pkgname"
# download dependencies
cargo fetch --target "$CARCH-unknown-linux-gnu"
}
build() {
cd "$pkgname"
cargo build --release --frozen
}
package() {
cd "$pkgname"
# binary
install -vDm755 -t "$pkgdir/usr/bin" target/release/{cargo-make,makers}
# license
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
# documentation
install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" *.md
# shell auto-completion
install -vDm644 extra/shell/makers-completion.bash "$pkgdir/usr/share/bash-completion/completions/makers"
}
|