blob: 3321d40e01a75d5abc2363d8ed8d909bf65a8909 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: orhun <orhunparmaksiz@gmail.com>
# Contributor: Vlad Frolov <frolvlad@gmail.com>
# https://github.com/orhun/pkgbuilds
pkgname=cargo-workspaces
pkgver=0.2.43
pkgrel=1
pkgdesc="Cargo plugin for managing cargo workspaces and their crates"
url="https://github.com/pksunkara/cargo-workspaces"
depends=('gcc-libs' 'openssl' 'zlib')
makedepends=('cargo')
arch=('x86_64')
license=('MIT')
source=("${pkgname}-${pkgver}.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('dbcbd7ac75ddd7eb520539e7a2f2c9c6e5dd82dcdd9db5b400e4588266d3bef3c099bde6a8072e28ddd2c601077a6cb8a628d70cd5130535b0795917bc8ea1bb')
options=('!lto')
prepare() {
cd "${pkgname}-${pkgver}/${pkgname}"
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}
build() {
cd "${pkgname}-${pkgver}/${pkgname}"
cargo build --release --frozen
}
check() {
cd "${pkgname}-${pkgver}/${pkgname}"
cargo test --frozen
}
package() {
cd "${pkgname}-${pkgver}"
install -Dm 755 "${pkgname}/target/release/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
# vim:set ts=2 sw=2 et:
|