blob: 008d5a1a391dd92688752f063b2557973b7320c2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Nikita Puzyryov <PuzyryovN@gmail.com>
pkgname=casync-git
pkgver=1.r17.ge1877ff
pkgrel=1
pkgdesc="Content-Addressable Data Synchronization Tool"
arch=(x86 x86_64)
url="https://github.com/systemd/casync"
license=('LGPL')
depends=('acl' 'libcurl.so' 'libgcrypt' 'xz' 'fuse2')
makedepends=('git' 'meson')
optdepends=()
checkdepends=('rsync')
provides=('casync')
conflicts=('casync')
source=("$pkgname::git+$url")
sha256sums=('SKIP')
pkgver() {
cd "$pkgname"
( set -o pipefail
git describe --tags 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
build() {
cd "$srcdir/$pkgname"
meson --buildtype=release --prefix=/usr build/
ninja -C build/
}
check() {
cd "$srcdir/$pkgname"
ninja -C build/ test
}
package() {
cd "$srcdir/$pkgname"
DESTDIR="$pkgdir/" ninja -C build/ install
}
|