blob: c3ebbe69a16eb4ae82495132d27b2994c3f980f0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Paul Hentschel (hpmachining)
pkgname=cbang
pkgver=1.3.1
pkgrel=3
pkgdesc="a library of cross-platform C++ utilities"
arch=('x86_64')
url="https://github.com/CauldronDevelopmentLLC/cbang"
license=('LGPL2.1')
depends=(
'v8-3.14'
'libevent'
'sqlite'
're2'
'libyaml'
'zlib'
'bzip2'
'expat'
)
makedepends=(
'scons'
)
checkdepends=(
'python2'
)
optdepends=(
'mariadb-libs: MariaDB database support'
)
source=(
"$pkgname-$pkgver.tar.gz::https://github.com/CauldronDevelopmentLLC/cbang/archive/$pkgver.tar.gz"
"0001_python3_fix.patch"
)
sha256sums=('23bf2997ac8438592545f1cde7cd076ba759f3f4a01e6540cdf45a97616eaaef'
'4047b8dcaeae671d631e4cfbc896833c861ecf1a1e1c3d873095d901515f7e11')
prepare() {
cd "$pkgname-$pkgver"
patch -p1 -i "../0001_python3_fix.patch"
}
build() {
cd "$pkgname-$pkgver"
scons disable_local="libevent sqlite3 re2 libyaml zlib bzip2 expat"
}
check() {
cd "$pkgname-$pkgver/tests"
scons
python2 ./testHarness
}
package() {
cd "$pkgname-$pkgver"
scons install prefix="$pkgdir/opt/$pkgname"
install -m644 lib/libcbang-boost.a -t "$pkgdir/opt/$pkgname/lib"
cp -a config/ "$pkgdir/opt/$pkgname/config/"
cp -a src/boost/boost/ "$pkgdir/opt/$pkgname/include/"
}
|