blob: b3e38cbc02c80effbedb8a673698bd365c200389 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: Paul Hentschel (hpmachining)
# Contributor: greyltc
pkgname=cbang-git
pkgver=1.3.3.r4.g32940672
pkgrel=1
pkgdesc="A library of cross-platform C++ utilities"
arch=('x86_64')
url="https://github.com/CauldronDevelopmentLLC/cbang"
license=('LGPL2.1')
depends=(
'v8-6.8'
'libevent'
'sqlite'
're2'
'libyaml'
'zlib'
'bzip2'
'expat'
)
makedepends=(
'git'
'scons'
)
checkdepends=(
'python2'
)
optdepends=(
'mariadb-libs: MariaDB database support'
)
conflicts=("${pkgname%-git}")
provides=("${pkgname%-git}")
source=("git+https://github.com/CauldronDevelopmentLLC/cbang.git")
sha256sums=('SKIP')
pkgver() {
cd "${pkgname%-git}"
git describe --long --tags | sed 's/^v//;s/-/.r/;s/-/./'
}
prepare() {
cd "${pkgname%-git}"
sed -i "/files = Glob('src\/cbang\/%s\/\*.h'/a\ files += Glob('include/cbang/%s/*.h' % dir)" SConstruct
sed -i "20i\ conf.CBRequireLib('v8_libplatform')" config/v8/__init__.py
}
build() {
cd "${pkgname%-git}"
scons disable_local="libevent sqlite3 re2 libyaml zlib bzip2 expat"
}
check() {
cd "${pkgname%-git}/tests"
scons
python2 ./testHarness
}
package() {
cd "${pkgname%-git}"
scons install prefix="$pkgdir/opt/${pkgname%-git}"
install -m644 lib/libcbang-boost.a -t "$pkgdir/opt/${pkgname%-git}/lib"
cp -a config/ "$pkgdir/opt/${pkgname%-git}/config/"
cp -a src/boost/boost/ "$pkgdir/opt/${pkgname%-git}/include/"
}
|