blob: 47da8358a0a1732d11e55a14aefcdf6b7ccfc4fb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
|
# Maintainer: Ethan M <SirEthanator@noreply.users.github.com>
pkgname=cbmp-rs
pkgver=1.1.0
pkgrel=1
pkgdesc='A CLI for converting cursor SVG files to PNG files.'
url='https://github.com/SirEthanator/cbmp-rs'
license=(MIT)
makedepends=('cargo')
depends=()
arch=('i686' 'x86_64' 'armv6h' 'armv7h')
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('d0735d5acd288371a6a09325d4cca6f971959ed8db135327876b6e1c82c25d16')
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$(rustc --print host-tuple)"
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release --all-features
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/cbmp"
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|