blob: 6fc29064d697803c365ef06270022d00712f605c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Firegem <mrfiregem [at] protonail [dot] ch>
pkgname=cbqn-git
pkgver=r686.2baa9ac
pkgrel=3
pkgdesc="A BQN implementation in C."
arch=('x86_64')
url="https://github.com/dzaima/CBQN"
license=('GPL3')
depends=('glibc')
optdepends=('rlwrap: Better REPL'
'ttf-bqn386: BQN and APL compatible font')
makedepends=('git' 'clang')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("${pkgname%-git}::git+${url}.git"
'makefile.patch')
md5sums=('SKIP'
'f23b43c3c37457cdb830eb7794ee945f')
pkgver() {
cd "${srcdir}/${pkgname%-git}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "${srcdir}/${pkgname%-git}"
patch --forward --strip=1 --input="${srcdir}/makefile.patch"
}
build() {
cd "$srcdir/${pkgname%-git}"
make PIE='-pie'
}
package() {
cd "$srcdir/${pkgname%-git}"
install -Dm755 BQN "${pkgdir}/usr/bin/bqn"
install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
|