blob: 5592701f608b35b518f1af2f0e1b55f9606b9094 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Sean Enck <enckse@gmail.com>
pkgname=ccid-git
pkgver=ccid.1.4.26.r35.g582f882
pkgrel=1
pkgdesc="A generic USB Chip/Smart Card Interface Devices driver (git version)"
arch=('i686' 'x86_64')
url="http://pcsclite.alioth.debian.org/ccid.html"
license=('LGPL' 'GPL')
depends=('pcsclite' 'libusb' 'flex')
makedepends=('pkg-config')
provides=("ccid")
conflicts=("ccid")
backup=(etc/reader.conf.d/libccidtwin)
source=("git+https://alioth.debian.org/anonscm/git/pcsclite/CCID.git"
"git+https://alioth.debian.org/anonscm/git/pcsclite/PCSC.git"
"git+https://anonscm.debian.org/git/pcsclite/contrib.git")
md5sums=('SKIP' 'SKIP' 'SKIP')
validpgpkeys=(F5E11B9FFE911146F41D953D78A1B4DFE8F9C57E) # Ludovic Rousseau <ludovic.rousseau@free.fr>
pkgver() {
cd "${srcdir}/CCID"
git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd ${srcdir}/CCID
git submodule init
git config submodule.PCSC.url $srcdir/PCSC
git config submodule.contrib_libPCSCv2part10.url $srcdir/contrib
git submodule update
}
build() {
cd "${srcdir}/CCID"
sed -i "/^AC\_INIT/ { s,]),-git]), }" configure.ac
./bootstrap
./configure --prefix=/usr \
--sysconfdir=/etc \
--enable-twinserial \
--enable-serialconfdir=/etc/reader.conf.d
make
}
package() {
cd "${srcdir}/CCID"
make DESTDIR="${pkgdir}" install
# move the configuration file in /etc and create a symbolic link
mv "${pkgdir}/usr/lib/pcsc/drivers/ifd-ccid.bundle/Contents/Info.plist" "${pkgdir}/etc/libccid_Info.plist"
ln -s /etc/libccid_Info.plist ${pkgdir}/usr/lib/pcsc/drivers/ifd-ccid.bundle/Contents/Info.plist
}
|