PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Maintainer: Claudia Pellegrino <aur ät cpellegrino.de>

_pkgbase=ccloader
pkgname=ccloader-git
pkgver=r14.2ad8a4f
pkgrel=3
pkgdesc='Burn CC2530/CC2531/CC2540/CC2541 firmware using an Arduino'
arch=('x86_64')
url='https://github.com/RedBearLab/CCLoader'
license=('custom:undecided')
depends=('glibc')
makedepends=('gcc' 'git')
provides=('ccloader')
conflicts=('ccloader')

source=(
  "${pkgname}::git+https://github.com/RedBearLab/CCLoader.git"
)

sha512sums=(
  'SKIP'
)

pkgver() {
  printf "r%s.%s" \
    "$(git -C "${pkgname}" rev-list --count HEAD)" \
    "$(git -C "${pkgname}" rev-parse --short HEAD)"
}

build() {
  cd "${srcdir}/${pkgname}/SourceCode/Linux"
  # shellcheck disable=SC2086 # we need the word splitting
  gcc ${CFLAGS} ${LDFLAGS} main.c -o "${_pkgbase}"
}

package() {
  echo >&2 'Packaging the executable'
  install -D -m 755 -t "${pkgdir}/usr/bin" \
    "${srcdir}/${pkgname}/SourceCode/Linux/${_pkgbase}"

  echo >&2 'Packaging the Arduino sketch'
  install -D -m 644 -t "${pkgdir}/usr/share/${pkgname}/Arduino/CCLoader" \
    "${srcdir}/${pkgname}/Arduino/CCLoader/CCLoader.ino"

  echo >&2 'Packaging README.md'
  install -D -m 644 -t "${pkgdir}/usr/share/doc/${_pkgbase}" \
    "${srcdir}/${pkgname}/"{CCLoader.jpg,README.md}
}