summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 002c68cce99f701a16472a1d440758d356de1367 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
# Maintainer: Omar Pakker <archlinux@opakker.nl>

_pkgname='ccminer'
pkgname="${_pkgname}-git"
pkgver=r917.b54be47
pkgrel=1
pkgdesc="Coin miner using CUDA for nVidia GPUs."
arch=('x86_64')
url="http://ccminer.org/"
license=('GPL3')
depends=('cuda' 'curl' 'jansson' 'nvidia-utils')
makedepends=('git' 'cuda' 'nvidia-utils')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
options=('!emptydirs')
source=("git+https://github.com/tpruvot/ccminer.git#branch=linux")
sha256sums=('SKIP')

pkgver() {
	cd "ccminer"

	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd "ccminer"

	./autogen.sh
	./configure CUDA_CFLAGS='--shared --compiler-options "-fPIC"' \
		--prefix=/usr --sysconfdir=/etc --libdir=/usr/lib --with-cuda=/opt/cuda

	make
}

package() {
	cd "ccminer"

	make DESTDIR="${pkgdir}" install
}