blob: 08d03ba9ad6c0096ec6e10a19262a773ab65b54b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Joffrey <j-off@live.fr>
# Contributor: eolianoe <eolianoe [at] gmail [DoT] com>
# Contributor: Aaron Lindsay <aaron@aclindsay.com>
# Contributor: Edvinas Valatka <edacval@gmail.com>
# Contributor: Adrian Hühn <adrian.huehn@web.de>
pkgname=ccnet-server
pkgver=7.1.1
pkgrel=1
pkgdesc="Internal communication framework and user/group management for seafile server"
arch=('i686' 'x86_64' 'armv7h' 'armv6h' 'aarch64')
url="https://github.com/haiwen/$pkgname"
license=('GPL2')
depends=('libevent' 'libsearpc' 'libldap' 'mariadb-libs' 'postgresql-libs')
makedepends=('vala')
conflicts=('ccnet')
provides=('ccnet')
source=("$pkgname-v$pkgver-server.tar.gz::$url/archive/v$pkgver-server.tar.gz")
sha256sums=('5b4196b8049d3d7b5a0d37292241f55e5b362b6894bc1d2e346c2e054941d0da')
prepare() {
cd "$srcdir/$pkgname-$pkgver-server"
sed -i "s|(DESTDIR)@prefix@|@prefix@|" "./libccnet.pc.in"
}
build() {
cd "$srcdir/$pkgname-$pkgver-server"
./autogen.sh
./configure \
--enable-ldap \
--enable-python \
--enable-console \
--prefix=/usr \
--with-mysql=/usr/bin/mysql_config \
PYTHON='/usr/bin/python'
make
}
package() {
cd "$srcdir/$pkgname-$pkgver-server"
make DESTDIR="$pkgdir" install
}
|