blob: bbb3946bde7883971f7b14a6cd2fca14aa9f8915 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Blair Bonnett <blair.bonnett at gmail>
pkgname=ccr
pkgver=2.0.0
pkgrel=1
pkgdesc='Community codec repository: compression (and other) filters for netCDF/HDF5'
url='https://ccr.github.io/ccr/'
license=('BSD-3-Clause')
arch=('x86_64')
depends=(
'sh'
'glibc'
'hdf5'
'lz4'
'netcdf'
)
source=(
"ccr-$pkgver.tar.gz::https://github.com/ccr/ccr/archive/refs/tags/v${pkgver//./_}.tar.gz"
'remove_old_tests.patch'
)
sha256sums=(
'a9b12720265b5a4d694c3e43de66c3aa3bdafd59106cc0f1b6b82b966687d8e6'
'84289938f2c05a4e235298a44fce06a50cabd620a61082f47ae036614a3a2bf6'
)
prepare() {
cd "$pkgname-${pkgver//./_}"
patch -p0 -i "$srcdir/remove_old_tests.patch"
autoreconf -fiv
}
build() {
cd "$pkgname-${pkgver//./_}"
./configure \
--prefix=/usr \
--with-hdf5-plugin-path=/usr/lib/hdf5/plugin
make
}
check() {
cd "$pkgname-${pkgver//./_}"
make check
}
package() {
cd "$pkgname-${pkgver//./_}"
make DESTDIR="$pkgdir" install
mkdir "$pkgdir/usr/lib/hdf5"
mv "$pkgdir/usr/local/hdf5/lib/plugin" "$pkgdir/usr/lib/hdf5"
rm -rf "$pkgdir/usr/local"
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}
|