blob: f44d8e459ec2b4e18357098e17a807a43cde596c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: carstene1ns <url/mail: arch carsten-teibes de>
# Contributor: jose riha <jose 1711 gmail com>
# Contributor: Christoph Zeiler <archNOSPAM_at_moonblade.dot.org>
# Contributor: nut543 <kfs1@online.no>
# Contributor: Dany Martineau <dany.luc.martineau at gmail.com>
pkgname=cdogs
pkgver=0.5.4
pkgrel=2
pkgdesc='SDL port of DOS arcade game C-Dogs (aka "Cyberdogs 2")'
arch=('i686' 'x86_64')
url="http://cxong.github.io/cdogs-sdl/"
license=('GPL2')
depends=('sdl_mixer' 'sdl_image')
makedepends=('cmake')
source=(cdogs-$pkgver.tar.gz::"https://github.com/cxong/cdogs-sdl/archive/$pkgver.tar.gz"
hqx-for-$pkgver.tar.gz::"https://github.com/cxong/hqx/archive/994249c8c4d1446afd9c05654bf7eafffd7a11bb.tar.gz"
cbehave-for-$pkgver.tar.gz::"https://github.com/cxong/cbehave/archive/e90cdcf2ebaedabb8f5a2595d6edf7c823a4f196.tar.gz"
rlutil-for-$pkgver.tar.gz::"https://github.com/cxong/rlutil/archive/97348047c4340de554bb0b5c6e0d2ab34c88f05b.tar.gz"
tinydir-for-$pkgver.tar.gz::"https://github.com/cxong/tinydir/archive/5545eeb7bf5ee2b64f790a276f89aa1856a6269a.tar.gz")
sha256sums=('675eab5e9fafe3254cd2a42435c37809d97050bd875c748184d59565a8dda276'
'adeef0711099da7e86c2c20b3fc40e63f32ea1e11ef0b9a98dacfc983f38f4ce'
'16fbb9d01d7c03701447621f51033d58e1853d622bbff2930148fadd4a8e8029'
'eca5ba880a64688591c556a0d125e0cc2b92c2c15b60e733a85f2a735728f9c7'
'ebd1c2c64724f5f5e1837e42bae1f5c67a0be4df09b7974c2d6a3d64c8314ea4')
prepare() {
# copy submodules to right location
cp -rup hqx-994249c8c4d1446afd9c05654bf7eafffd7a11bb/* $pkgname-sdl-$pkgver/src/cdogs/hqx
cp -rup cbehave-e90cdcf2ebaedabb8f5a2595d6edf7c823a4f196/* $pkgname-sdl-$pkgver/src/tests/cbehave
cp -rup rlutil-97348047c4340de554bb0b5c6e0d2ab34c88f05b/* $pkgname-sdl-$pkgver/src/tests/cbehave/rlutil
cp -rup tinydir-5545eeb7bf5ee2b64f790a276f89aa1856a6269a/* $pkgname-sdl-$pkgver/src/tinydir
cd $pkgname-sdl-$pkgver
# disable -Werror (aborts build)
sed 's|add_definitions(-Winline -Werror)|add_definitions(-Winline)|' -i CMakeLists.txt
# fix name in .desktop file
sed 's|Exec=cdogs-sdl|Exec=cdogs|g' -i build/linux/cdogs-sdl.desktop
}
build() {
cd $pkgname-sdl-$pkgver
cmake ./ -DDESTDIR=/opt/cdogs/bin
make
}
package() {
cd $pkgname-sdl-$pkgver
# launcher + binary
install -Dm755 build/linux/cdogs-sdl "$pkgdir"/usr/bin/cdogs
install -Dm755 src/cdogs-sdl "$pkgdir"/opt/cdogs/bin/cdogs-sdl
# data
cp -r dogfights graphics missions music sounds "$pkgdir"/opt/cdogs/
# doc
install -d "$pkgdir"/usr/share/doc/cdogs
cp -r doc/* "$pkgdir"/usr/share/doc/cdogs
ln -s /usr/share/doc/cdogs/ "$pkgdir"/opt/cdogs/doc
# .desktop file
install -Dm644 build/linux/cdogs-icon.48.png "$pkgdir"/usr/share/pixmaps/cdogs_icon.png
install -Dm644 build/linux/cdogs-sdl.desktop "$pkgdir"/usr/share/applications/cdogs.desktop
}
|