blob: 5f3f25226922d5af9ce9d3a97435f60de639b11c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: ikolan
# Contributors: carstene1ns, jose riha, Christoph Zeiler, nut543 and Dany Martineau
pkgname=cdogs
pkgver=1.4.0
pkgrel=1
pkgdesc='Enhanced SDL port of DOS arcade game C-Dogs (aka "Cyberdogs 2")'
arch=('i686' 'x86_64')
url="http://cxong.github.io/cdogs-sdl/"
license=('GPL2')
depends=('gtk3' 'sdl2_mixer' 'sdl2_image')
makedepends=('cmake' 'python-pip' 'python-protobuf')
optdepends=('cdogs-mission-pack: A large collection of user-created campaigns for C-Dogs.')
source=(cdogs-$pkgver.tar.gz::"https://github.com/cxong/cdogs-sdl/archive/${pkgver}.tar.gz")
sha256sums=('4030bd8f6168b8f7ee152d0edb1d7a4b75920b7b7fb19a2f7e834508af9631cd')
prepare() {
cd $pkgname-sdl-$pkgver
# disable -Werror (aborts build on mere warnings)
sed 's| -Werror||' -i CMakeLists.txt
}
build() {
cd $pkgname-sdl-$pkgver
cmake ./ -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=/usr/share/cdogs \
-DCDOGS_DATA_DIR="/usr/share/cdogs/"
make
}
package() {
make DESTDIR="$pkgdir/" install -C $pkgname-sdl-$pkgver
mv $pkgdir/usr/share/cdogs/bin/ $pkgdir/usr/bin/
mv $pkgdir/usr/share/cdogs/share/* $pkgdir/usr/share/
}
|