blob: eee6c42b6b184b09e55d1f1e6b595abc4e33b545 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=cedilla
pkgver=0.1.10
pkgrel=1
pkgdesc="A markdown text editor for the COSMIC™ desktop"
arch=('x86_64' 'aarch64')
url="https://github.com/mariinkys/cedilla"
license=('GPL-3.0-or-later')
depends=(
'fontconfig'
'hicolor-icon-theme'
'libxkbcommon'
)
makedepends=(
'cargo'
'just'
)
checkdepends=(
'appstream'
'desktop-file-utils'
)
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/$pkgver.tar.gz")
sha256sums=('9415e124dca6f0ef30b583b3f064c27884da77711f0dcefe209fac1dcc8eb886')
prepare() {
cd "$pkgname-$pkgver"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target host-tuple
}
build() {
cd "$pkgname-$pkgver"
CFLAGS+=" -ffat-lto-objects"
export RUSTUP_TOOLCHAIN=stable
just build-release --frozen
}
check() {
cd "$pkgname-$pkgver"
appstreamcli validate --no-net resources/app.metainfo.xml
desktop-file-validate resources/app.desktop
}
package() {
cd "$pkgname-$pkgver"
just rootdir="$pkgdir" install
}
|