PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

# Maintainer: Simon Brulhart <simon@brulhart.me>
# Contributor: Suhaimi Ghazali <serdotlinecho@gmail.com>
# Contributor: Patrick Griffis <tingping@tingping.se>

pkgname=celluloid-git
pkgver=0.27.r26.gb027fa8
pkgrel=1
pkgdesc="Simple GTK+ frontend for mpv"
arch=('i686' 'x86_64')
url="https://celluloid-player.github.io/"
license=('GPL-3.0-or-later')
depends=('gtk4' 'libadwaita' 'mpv')
makedepends=('appstream-glib' 'git' 'glib2-devel' 'meson')
optdepends=('youtube-dl: for video-sharing websites playback')
conflicts=('celluloid')
provides=('celluloid')
source=("$pkgname::git+https://github.com/celluloid-player/celluloid.git")
md5sums=('SKIP')

pkgver() {
    cd "$pkgname"
    git describe --long --tags | sed -r 's/^v//;s/([^-]*-g)/r\1/;s/-/./g'
}

build() {
  arch-meson "$pkgname" build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
    meson install -C build --destdir "$pkgdir"
}