blob: 72051d3643ce99271c2a2942002cef67a1b611ef (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Maintainer: Maxim Baz <cerebro@maximbaz.com>
pkgname=cerebro
pkgver=0.3.0
pkgrel=1
pkgdesc='Open-source productivity booster with a brain.'
arch=('x86_64' 'i686')
url='https://cerebroapp.com/'
license=('MIT')
conflicts=('cerebro-git')
depends=('alsa-lib' 'gconf' 'gtk2' 'libxss' 'libxtst' 'nss')
makedepends=('gendesk' 'python' 'yarn' 'npm')
provides=('cerebro')
source=("${pkgver}.tar.gz::https://github.com/KELiON/cerebro/archive/v"$pkgver".tar.gz")
sha256sums=('1de8076566b14f4472ea45711bb56d7f41c0e8e0f16690fff2c57e33f4d5f392')
prepare() {
gendesk -f -n --name=Cerebro --pkgname="${pkgname}" --pkgdesc="${pkgdesc}" --exec="${pkgname}" --categories="System"
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
yarn && cd ./app && yarn && cd ../
yarn run build
if [ $CARCH == 'x86_64' ]; then
node_modules/.bin/build --linux --x64 --dir
elif [ $CARCH == 'i686' ]; then
node_modules/.bin/build --linux --ia32 --dir
else
echo "Unknown architecture"; exit 1;
fi
}
package() {
# Place files
install -d "${pkgdir}/usr/lib/${pkgname}"
if [ $CARCH == 'x86_64' ]; then
cp -a "${srcdir}/${pkgname}-${pkgver}/release/linux-unpacked/"* "${pkgdir}/usr/lib/${pkgname}"
elif [ $CARCH == 'i686' ]; then
cp -a "${srcdir}/${pkgname}-${pkgver}/release/linux-ia32-unpacked/"* "${pkgdir}/usr/lib/${pkgname}"
else
echo "Unknown architecture"; exit 1;
fi
# Symlink main binary
install -d "${pkgdir}/usr/bin"
ln -s "/usr/lib/${pkgname}/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
# Place desktop entry and icon
desktop-file-install -m 644 --dir "${pkgdir}/usr/share/applications/" "${srcdir}/${pkgname}.desktop"
for res in 16x16 32x32 48x48 128x128 256x256 512x512 1024x1024; do
install -dm755 "${pkgdir}/usr/share/icons/hicolor/${res}/apps"
install -Dm644 "${srcdir}/${pkgname}-${pkgver}/build/icons/${res}.png" \
"${pkgdir}/usr/share/icons/hicolor/${res}/apps/${pkgname}.png"
done
# Place license files
for license in "LICENSE.electron.txt" "LICENSES.chromium.html"; do
install -Dm644 "${pkgdir}/usr/lib/${pkgname}/${license}" "${pkgdir}/usr/share/licenses/${pkgname}/${license}"
rm "${pkgdir}/usr/lib/${pkgname}/${license}"
done
}
|