blob: 5861d0044701522d619c11a239f7d4a4eab83d79 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# Maintainer: Daniel Peukert <daniel@peukert.cc>
_pkgname='certspotter'
pkgname="$_pkgname-git"
pkgver='0.15.0.r0.gce81f90'
pkgrel='1'
pkgdesc='Certificate Transparency Log Monitor - git version'
arch=('x86_64' 'i686' 'arm' 'armv6h' 'armv7h' 'aarch64')
url="https://github.com/SSLMate/$_pkgname"
license=('MPL2')
makedepends=('git' 'go>=1.19' 'lowdown')
provides=("$_pkgname")
conflicts=("$_pkgname")
install="$_pkgname.install"
source=(
"$pkgname::git+$url"
"$pkgname-$pkgver-$pkgrel-fix-errorf.diff::$url/pull/67.diff"
)
sha512sums=('SKIP'
'9a27893c2ddbb7634e4316b63f7b6ba4686a44d27b9d128f627514fface7251f154d4dbb1300ba39d1290149a3c0879d232f523681cf577ddcc9e8b519fae0eb')
_sourcedirectory="$pkgname"
_bindir="$pkgname-bin"
_gopath="$pkgname-gopath"
prepare() {
mkdir -p "$srcdir/$_bindir/"
mkdir -p "$srcdir/$_gopath/"
# Apply errorf patch
cd "$srcdir/$_sourcedirectory/"
patch --forward -p1 < "$srcdir/$pkgname-$pkgver-$pkgrel-fix-errorf.diff"
}
pkgver() {
cd "$srcdir/$_sourcedirectory/"
git describe --long --tags | sed -e 's/^v//' -e 's/-\([^-]*-g[^-]*\)$/-r\1/' -e 's/-/./g'
}
build() {
cd "$srcdir/$_sourcedirectory/"
export GOPATH="$srcdir/$_gopath"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
go build -v -o "$srcdir/$_bindir/" './...'
# Build man pages
cd "$srcdir/$_sourcedirectory/man/"
make all
}
check() {
cd "$srcdir/$_sourcedirectory/"
export GOPATH="$srcdir/$_gopath"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
go test -v './...'
}
package() {
cd "$srcdir/"
install -dm755 "$pkgdir/usr/bin/"
install -Dm755 "$_bindir/"* "$pkgdir/usr/bin/"
install -dm755 "$pkgdir/usr/share/man/man8/"
install -Dm644 "$_sourcedirectory/man/"*'.8' "$pkgdir/usr/share/man/man8/"
}
|