blob: 7839cc6fc37c7f9f56f97bec063ca2bf9a9bc59f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer: Peter blackman <peter at pblackman dot plus dot com>
#
pkgname=cevomapgen
pkgver=28
pkgrel=1
pkgdesc="External Random Map Generator for C-evo"
arch=('x86_64' 'aarch64')
url="https://sourceforge.net/projects/$pkgname"
license=('GPL')
depends=('qt5pas' 'glibc' 'libx11' 'hicolor-icon-theme')
makedepends=('fpc' 'lazarus-qt5')
source=("$url/files/Source/${pkgname}_${pkgver}.orig.tar.xz"
"$url/files/Source/${pkgname}_${pkgver}.orig.tar.xz.asc")
sha256sums=('1c3e01c8a44221408513ff2a2e44c2563d352dc95a11ad3616b40826dd20ad16'
'SKIP')
validpgpkeys=(14638444C9858E2A09B0259C211BCF562939AB8F)
prepare() {
cd "$srcdir/$pkgname-$pkgver"
# Set temporary folder for lazarus primary config
rm -fr "$srcdir/config"
mkdir "$srcdir/config"
# Don't need Windows docs on Arch
rm -f "Docs/ReadmeWindows.html"
# Move desktop files
rm -fr Desktop
mkdir Desktop
mv "Docs/cevomapgen.svg" Desktop
mv "Docs/$pkgname.desktop" Desktop
# currently cannot build with -pie as the RTL is not built with pie
sed -i '/-k-pie/d' fpc.cfg
}
build() {
cd "$srcdir/$pkgname-$pkgver"
# clean
rm -fr lib
rm -f *.res
lazbuild -v
lazbuild --ws=qt5 -B --lazarusdir=/usr/lib/lazarus --pcp="$srcdir/config" CevoMapGen.lpi
}
package() {
cd "$pkgname-$pkgver"
install -p -Dm 755 "$pkgname" -t "$pkgdir/usr/bin"
install -p -Dm 644 "Desktop/cevomapgen.svg" -t "$pkgdir/usr/share/icons/hicolor/scalable/apps"
install -p -Dm 644 "Desktop/$pkgname.desktop" -t "$pkgdir/usr/share/applications"
install -p -Dm 644 Templates/*.INI -t "$pkgdir/usr/share/$pkgname/Templates"
install -p -Dm 644 Docs/*.html -t "$pkgdir/usr/share/doc/$pkgname"
}
|