blob: fe864135da286bb1865a11a2f65c45f73d5717da (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: Christian Hesse <mail@eworm.de>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Lukas Fleischer <archlinux at cryptocrack dot de>
# Contributor: Patrick Palka <patrick@parcs.ath.cx>
# Contributor: Loui Chang <louipc.ist at gmail com>
# Contributor: Andreas Baumann <abaumann at yahoo dot com>
pkgname=cgit-git
pkgver=0.11.2.r12.gda1d4c7
pkgrel=1
pkgdesc='A web interface for git written in plain C - git checkout'
arch=('i686' 'x86_64')
url='http://git.zx2c4.com/cgit/'
license=('GPL2')
depends=('openssl' 'luajit')
makedepends=('git' 'zlib' 'curl' 'asciidoc')
optdepends=('python2-pygments: syntax highlighting support'
'mime-types: serve file with correct content-type header')
conflicts=('cgit')
provides=('cgit')
install=cgit.install
source=('git://git.zx2c4.com/cgit.git'
'git://github.com/git/git.git'
'apache.example.conf')
sha256sums=('SKIP'
'SKIP'
'89927d462c0504863c163eb8a210e5d65db30ee6e4300ff6a2f92460e4f20a62')
pkgver() {
cd cgit/
if GITTAG="$(git describe --abbrev=0 --tags 2>/dev/null)"; then
printf '%s.r%s.g%s' \
"$(sed -e "s/^${pkgname%%-git}//" -e 's/^[-_/a-zA-Z]\+//' -e 's/[-_+]/./g' <<< ${GITTAG})" \
"$(git rev-list --count ${GITTAG}..)" \
"$(git log -1 --format='%h')"
else
printf '0.r%s.g%s' \
"$(git rev-list --count master)" \
"$(git log -1 --format='%h')"
fi
}
prepare() {
cd cgit/
git config --file=.gitmodules submodule.git.url ../git/
git submodule init
git submodule update
}
build() {
cd cgit/
make
make doc-man
}
package() {
cd cgit/
make CGIT_SCRIPT_PATH=/usr/share/webapps/cgit DESTDIR="${pkgdir}" prefix=/usr install install-man
install -vd "${pkgdir}/var/cache/cgit"
install -vDm0644 "${srcdir}/apache.example.conf" "${pkgdir}/etc/webapps/cgit/apache.example.conf"
install -d "${pkgdir}/usr/lib/cgit"
mv "${pkgdir}/usr/share/webapps/cgit/cgit.cgi" "${pkgdir}/usr/lib/cgit"
ln -sf ../../../lib/cgit/cgit.cgi "${pkgdir}/usr/share/webapps/cgit/cgit.cgi"
}
|