blob: b94bf8b74d0708fa2982aa9f78597b36e1f87195 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Thomas Lindae <thomas.lindae@in.tum.de>
# Contributor: teraflops <cprieto.ortiz@gmail.com>
pkgname=chameleos-git
pkgver=0.1.0.r1.g4663dab
pkgrel=1
pkgdesc='Screen annotation tool for niri and Hyprland'
arch=('x86_64' 'aarch64')
url='https://github.com/Treeniks/chameleos'
license=('MIT')
depends=('wayland')
makedepends=('cargo' 'rust' 'git')
provides=('chameleos' 'chamel')
conflicts=('chameleos' 'chameleos-bin')
source=("$pkgname::git+$url")
options=(!debug)
sha256sums=(SKIP)
pkgver() {
cd "$pkgname"
git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "$pkgname"
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "$srcdir/$pkgname"
cargo build --frozen --release
}
package() {
cd "$srcdir/$pkgname"
install -Dm755 "target/release/chameleos" "$pkgdir/usr/bin/chameleos"
install -Dm755 "target/release/chamel" "$pkgdir/usr/bin/chamel"
install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|