PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Maintainer: João Figueiredo <islandc0der@chaotic.cx>

pkgname=chaos-equations-git
pkgver=r19.0fc5e2f
pkgrel=2
pkgdesc='Simple mathematical art'
arch=($CARCH)
url='https://github.com/MadManGaz/Chaos-Equations'
license=(MIT)
depends=(gcc-libs glibc libgl sfml)
makedepends=(git cmake)
conflicts=(${pkgname%-git})
provides=(${pkgname%-git})
source=("git+$url.git" font.patch)
sha256sums=('SKIP'
            '0778dcb913966d5546c0f9e1df065040bd790971c85eb67355a363bd3cd24c32')

pkgver() {
	cd Chaos-Equations
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
	cd Chaos-Equations
	patch -p1 -i ../font.patch
}

build() {
	cmake -B build -G "Unix Makefiles" -S Chaos-Equations \
		-DCMAKE_BUILD_TYPE=Release
	cmake --build build
}

package() {
	install -Dm755 build/chaosequations -t "$pkgdir/usr/bin/"
	install -Dm644 Chaos-Equations/LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}